Nächste Seite: F.3 Spezifikation der Syntax Vorige Seite: F.1 Spezifikation der Syntax

F.2 Spezifikation der Syntax der IPC-Nachrichten

 

Syntax der IPC-Nachrichten, die von einem Client an den ConceptBase-Server geschickt werden.

 <ipcmessage>    -->  ipcmessage(<sender> , <receiver> , <method_args> ) .

 <sender>        -->  IPCSTRING

 <receiver>      -->  IPCSTRING

 <method_args>   -->  <tell>

                   |   <tellmodel>

                   |   <untell>

                   |   <ask>

                   |   <hypoask>

                   |   <notifyrequest>

                   |   <enrollme>

                   |   <cancelme>

                   |   <nextmessage>

                   |   <stopserver>

                   |   <reportclients>

                   |   <lpicall>

 <tell>          -->  TELL , [ <telosframes>  ]

 <tellmodel>     -->  TELL_MODEL , [ <filelist>  ]
  
 <filelist>      -->   [ <ipcstringlist>  ]

 <untell>        -->   UNTELL , [ <telosframes>  ]

 <ask>           -->   ASK , [ <askargs>  ]

 <askargs>        -->  <query>  , <answerrep>  , <rollbacktime>

 <query>          -->  FRAMES , <telosframes>

                    |  OBJNAMES , <objnames>

 <objnames>       -->  IPCSTRING

 <answerrep>      -->  IPCSTRING

 <rollbacktime>   -->  IPCSTRING

 <hypoask>        -->  HYPO_ASK , [ <telosframes>  , <askargs>  ]

 <notifyrequest>  -->  NOTIFICATION_REQUEST , [[ <ipcstringlist>  ]]

 <enrollme>       -->  ENROLL_ME , [ <toolclass>  , <username>  ]

 <toolclass>      -->  IPCSTRING

 <username>       -->  IPCSTRING

 <cancelme>       -->  CANCEL_ME , [ ]

 <nextmessage>    -->  NEXT_MESSAGE , [ <method>  ]

 <method>         -->  ffl

                    |  IPCID

 <stopserver>     -->  STOP_SERVER , [ <method>  ]

 <reportclients>  -->  REPORT_CLIENTS , [ ]

 <lpicall>        -->  LPI_CALL , [ IPCSTRING ]

 <telosframes>    -->  IPCSTRING

 <ipcstringlist>  -->  IPCSTRING

                    |  <ipcstringlist>  , IPCSTRING

 IPCSTRING        -->  alles innerhalb von " ausser " und \, die \

                       als Pr"afix haben m"ussen

 IPCID            -->  [a-zA-Z]+[a-zA-Z0-9_]*

Syntax der IPC-Antworten, die der ConceptBase-Server an einen Client geschickt werden.

    <ipcanswer>    -->  ipcanswer(<sender> , <completion> , <result> )
	
    <sender>       -->  IPCSTRING

    <completion>   -->  ok

                     |  error

                     |  notification

                     |  not_handled

    <result>       -->  IPCSTRING